Formatting Trace result for external text viewer

Filed in Mathematica, Trace

Sometimes it might be more convenient to view Mathematica code in external plain-text editor. Reading the massive amounts of result returned by Trace is one of the typical cases. Mathematica FrontEnd is simply not a good choice for viewing hundreds of thousands lines of code.

Good for us, we have Sublime Text! But before that, we’ll need to properly format the exported code text — more precisely properly indent it to a ST friendly form.

With this levelIndentFunc function we can indent nested list according with the depths the commands are in:

Clear[levelIndentFunc]
levelIndentFunc[lst_] :=
 MapIndexed[
    {ConstantArray["\t", Length[#2] - 1], #1, "\n"} &,
    lst /. e_HoldForm :> StringTake[ToString[e, InputForm], {10, -2}],
    {-1}] // Flatten // StringJoin

Usage:

traceRes = Trace[Reduce[x^2 == -1, x], TraceInternal -> True, TraceDepth -> 3];
Export["tracePrintTest.txt", levelIndentFunc@traceRes, "String"]

Open tracePrintTest.txt in Sublime Text with Mathematica syntax highlight plugin enabled:

Reduce[x^2 == -1, x]
    General::meprec
    "Internal precision limit $MaxExtraPrecision = 1 reached while evaluating 2."
    Off[General::meprec]
        General::meprec
        "Internal precision limit $MaxExtraPrecision = 1 reached while evaluating 2."
    Null
    $MessageList = {}
    {}
    FactorList[1 + x^2]
    {{1, 1}, {1 + x^2, 1}}
    And[1 + x^2 == 0]
    1 + x^2 == 0
    And[]
    True
    Min[{0, 2}]
    0
    GCD[0, 2]
    2
        Quartics -> False
        Quartics -> False
    Roots[1 + x == 0, x, Cubics -> False, Quartics -> False]
        (1 + x) - 0
        1 + x
        $MessageList = {}
        {}
        $MessageList
        {}
        $MessageList = {}
        {}
        $MessageList
        {}
        $MessageList = {}
        {}
        $MessageList
        {}
        FactorSquareFree[-1]
        -1
        FactorTermsList[-1]
        {-1, 1}
    x == -1
    Or[x == -I || x == I]
    x == -I || x == I
    Or[x == -I || x == I]
    x == -I || x == I
    Union[{}]
    {}
    On[General::meprec]
        General::meprec
        $Off["Internal precision limit $MaxExtraPrecision = 1 reached while evaluating 2."]
    Null
x == -I || x == I

A simple flare star :)

Filed in Graphics, Mathematica, StackExchangeTags:

(Original post on Mma.SE)

flarerays = Normalize /@ RandomVariate[NormalDistribution[], {500, 3}];
    
Graphics3D[{
  White, Specularity[.1, 10], Sphere[],
  Opacity[.1],
  Orange,
  Line[{{1, 1, 2}, {1, 1, 2} + 10 #}] & /@ flarerays,
  Blue,
  Line[{{-1, 1, -1}, {-1, 1, -1} + 10 #}] & /@ flarerays
  },
 Lighting -> {
   {"Point", Orange, {1, 1, 2}},
   {"Point", Blue, {-1, 1, -1}}
   },
 PlotRange -> {{-2, 2}, {-2, 2}, {-2, 3}},
 Background -> Black]

flare stars

Draw a 3D cross-section of a 3-torus

Filed in Mathematica, Plot, StackExchange, [function test]Tags:

Problem

Someone asked this question on Mathematica.StackExchange:

I have a $3$-torus ($\mathbf S^1\times\mathbf S^1\times \mathbf S^1$) embedded in 4D Euclidean space. How can I draw the cross-section of this $3$-torus cut by a 3D Euclidean space in an arbitrary direction? The equations are: $$\begin{align*} x &= (r + (t + d\cos a)\cos b)\cos c\\ y &= (r + (t + d\cos a)\cos b)\sin c\\ z &= (t + d\cos a)\sin b\\ w &= d\sin a \end{align*}$$ where $x,y,z,w$ are the orthogonal coordinates in 4D space, $r,t,d$ are the radii of three circles, and $a,b,c$ denote the angles of the point with respect to the three circles.

Solution

So here is how I’ll handle it.

Take $r=1, t=5, d=10$ for example:

r = 1; t = 5; d = 10;

The parametric equation for the 3-torus is given by:

torus3 = {(r + (t + d Cos[a]) Cos[b]) Cos[c],
          (r + (t + d Cos[a]) Cos[b]) Sin[c],
          (t + d Cos[a]) Sin[b], d Sin[a]};

Suppose the plane is determined by its normal $\mathbf n$ and a point $\mathbf o$ on it:

\[DoubleStruckN] = Normalize[RandomReal[{0, 1}, 4]]
\[DoubleStruckO] = RandomReal[{-.5, .5}, 4]

So the cross section gives a constraint on $a, b, c$, which is $(\text{torus3}-\mathbf{o})\cdot\mathbf{n}=0$, which then defines a contour surface paraRegion in 3D Euclidean space (didn’t take the full $[0, 2\pi]$ ranges, so later we can see some inner structure of the cross section surface):

paraRegion = 
 ContourPlot3D[
  Evaluate[(torus3 - \[DoubleStruckO]).\[DoubleStruckN] == 0],
  {a, .4 π, 2π - .93 π}, {b, 0, 2 π-.1 π}, {c, 0, 2 π - .2 π},
  PlotRange -> All,
  ColorFunction -> Function[{a, b, c, f}, Hue[b, c, a]],
  PlotPoints -> 6, MaxRecursion -> 2,
  BoundaryStyle -> Directive[{Thickness[.01], GrayLevel[.7]}],
  MeshFunctions -> {#1 &, #2 &, #3 &},
  MeshStyle -> {RGBColor[1, .5, .5], RGBColor[.5, 1, .5], RGBColor[.5, .5, 1]},
  Lighting -> "Neutral",
  AxesLabel -> (Style[#, 20, Bold] & /@ {a, b, c})]

initial contour surface

Thanks to the plane, we can reduce the cross section into 3D Euclidean space:

crossEq = RotationMatrix[{\[DoubleStruckN], {0, 0, 0, 1}}].torus3 // Most

So we can further transform the feasible $(a,b,c)$ set paraRegion to the cross section surface we want:

Cases[paraRegion,
   GraphicsComplex[pts_, others_,
     opts1___, VertexNormals -> vn_, opts2___] :>
    GraphicsComplex[
     Function[{a, b, c}, Evaluate[crossEq]] @@ # & /@ pts,
     others, opts1, opts2], ∞][[1]] // Graphics3D[#,
   Axes -> True, PlotRange -> All, Lighting -> "Neutral"] &

3-torus with cut-away

Remark

Please beware that there are disadvantages of the above method, because Polygons in the cross section surface are directly inherited from the feasible parameter surface. To make sure this is correct, an assumption has to be made that the cross section surface must be continuous over the whole of paraRegion.

Protected: PlugIns Test

Filed in [function test]Tags: , , ,

This post is password protected. To view it please enter your password below:

Hello world!

Filed in Uncategorized

Welcome to WordPress. This is your first post. Edit or delete it, then start blogging!